Create a Flash game like ColorFill – part 1

Mouse.hide();
// flag indicating if I pressed space
space_pressed = false;
// vertical_arrow = true: arrows are horizontal
// vertical_arrow = false: arrows are vertical
vertical_arrow = false;
// flag indicating if I pressed space
clicked = false;
// enemy's random angle movement 
angle = Math.random()*360;
// enemy and arrows speeds
speed = 5;
// booleans that states if the left or right arrows touched the border of the stage
left_touch = false;
right_touch = false;
// x and y speeds of the enemy
xspeed = speed*Math.cos(angle*0.0174532925);
yspeed = speed*Math.sin(angle*0.0174532925);
// enemy collision detection precision
precision = 16;
// attaching the ball = the enemy
_root.attachMovie("ball","ball",1,{_x:250, _y:200});
// creating the empty movieclip that will contain all drawings
_root.createEmptyMovieClip("line",2);
// attaching the left arrow
_root.attachMovie("left_arrow","left_arrow",3);
// attaching the right arrow
_root.attachMovie("right_arrow","right_arrow",4);
// function to be executed for the left arrow
left_arrow.onEnterFrame = function() {
	// if I did not click the mouse
	if (!clicked) {
		// if I am not in "vertical mode"...
		if (!vertical_arrow) {
			// place the arrow
			this._y = _root._ymouse;
			this._x = _root._xmouse-15;
			this._rotation = 0;
		}
		// if I am in "vertical mode"....
		else {
			// place the arrow
			this._y = _root._ymouse-15;
			this._x = _root._xmouse;
			this._rotation = 90;
		}
	}
	// if I clicked the mouse....
	else {
		// if the arrow did not touch the edge of the stage...
		if (!left_touch) {
			// if I am not in "vertical mode"...
			if (!vertical_arrow) {
				// moving the arrow
				this._x -= speed;
				// checking if the arrow touched the left edge of the stage
				if (this._x<8) {
					this._x = 8;
					left_touch = true;
				}
			}
			// if I am in "vertical mode"...
			else {
				// moving the arrow
				this._y -= speed;
				// checking if the arrow touched the upper edge of the stage
				if (this._y<8) {
					this._y = 8;
					left_touch = true;
				}
			}
		}
	}
};
// same concept for the right arrow
right_arrow.onEnterFrame = function() {
	if (!clicked) {
		if (!vertical_arrow) {
			this._y = _root._ymouse;
			this._x = _root._xmouse+15;
			this._rotation = 0;
		}
		else {
			this._y = _root._ymouse+15;
			this._x = _root._xmouse;
			this._rotation = 90;
		}
	}
	else {
		if (!right_touch) {
			if (!vertical_arrow) {
				this._x += speed;
				if (this._x>492) {
					this._x = 492;
					right_touch = true;
				}
			}
			else {
				this._y += speed;
				if (this._y>392) {
					this._y = 392;
					right_touch = true;
				}
			}
		}
	}
};
// function to be executed for the ball... it's a simple "bounce here and there"
ball.onEnterFrame = function() {
	this._x += xspeed;
	this._y += yspeed;
	if ((this._x<20) or (this._x>480)) {
		xspeed *= -1;
	}
	if ((this._y<20) or (this._y>380)) {
		yspeed *= -1;
	}
};
// function to be executed at every frame
_root.onEnterFrame = function() {
	// if I did not pressed the space....
	if (!space_pressed) {
		// checking if I am pressing the space
		if (Key.isDown(Key.SPACE)) {
			space_pressed = true;
			// switching vertical_arrow state between true and false
			vertical_arrow = !vertical_arrow;
		}
	}
	// if I pressed space...
	else {
		// checking if I released the space
		if (!Key.isDown(Key.SPACE)) {
			space_pressed = false;
		}
	}
	// checking if I clicked the mouse
	if (clicked) {
		// preparing the line style
		line.clear();
		line.lineStyle(5,"0xff0000");
		// drawing a line from an arrow to the other
		line.moveTo(left_arrow._x,left_arrow._y);
		line.lineTo(right_arrow._x,right_arrow._y);
		// checking collision between the ball and the line
		for (x=1; x<precision; x++) {
			spot_x = ball._x+20*Math.sin(x*360/precision*0.0174532925);
			spot_y = ball._y+20*Math.cos(x*360/precision*0.0174532925);
			// if the ball touched the line...
			if (line.hitTest(spot_x, spot_y, true)) {
				// clear the line
				clicked = false;
				left_touch = false;
				right_touch = false;
				line.clear();
			}
		}
	}
	// if both left and right arrow (or up and down ones) touched the game edge...
	if (right_touch and left_touch) {
		// clear the line
		clicked = false;
		left_touch = false;
		right_touch = false;
		line.clear();
	}
};
// checking if I click the mouse
_root.onMouseDown = function() {
	if (!clicked) {
		clicked = true;
	}
};