Flash obstacle avoidance prototype

// movieclip that will host all obstacles
createEmptyMovieClip("obstacles", 1);
// placing 20 obstacles and the player
for (x=1; x<=21; x++) {
	// can_place = true: I can place the obstacle / false: I can't
	// initializing it to false to force entering the while loop
	can_place = false;
	// while loop to look for an empty space where to place the obstacle
	while (!can_place) {
		// setting can_place to true
		// you can always place an obstacle until you can't...
		can_place = true;
		// generating random x and y positions, and random width
		px = Math.floor(Math.random()*400)+50;
		py = Math.floor(Math.random()*400)+50;
		// if I am at the end of the cycle, it's time to place the runner
		if (x == 21) {
			w = 20;
		} else {
			w = Math.floor(Math.random()*100)+10;
		}
		// scanning all already placed obstacles
		for (y=x-1; y>=1; y--) {
			// determining the distance between the y-th obstacle and the one I am trying to place
			dist_x = px-obstacles["sphere_"+y]._x;
			dist_y = py-obstacles["sphere_"+y]._y;
			distance = Math.ceil(Math.sqrt(dist_x*dist_x+dist_y*dist_y));
			// this is the minimum distance I want between two obstacles:
			// the sum of both radiuses plus 20 pixels
			min_distance = (w+obstacles["sphere_"+y]._width)/2+20;
			// if the new obstacle would be too close to an existing one...
			if (distance<min_distance) {
				// set can_place to false
				can_place = false;
			}
		}
	}
	// I exited the while loop so I can place the unit...
	// ... or the runner...
	if (x == 21) {
		_root.attachMovie("runner", "runner", x, {_x:px, _y:py, _width:w, _height:w});
	} else {
		obstacles.attachMovie("sphere", "sphere_"+x, x, {_x:px, _y:py, _width:w, _height:w});
	}
}
// this movieclip is used only to visually trace the line of sight
createEmptyMovieClip("collisions", _root.getNextHighestDepth());
// random starting angle, in radians
angle = Math.random(6.28318531);
// starting speed
speed = 2;
// minimum speed, negative to allow runner to make some steps backward
min_speed = -2;
// maximum speed
max_speed = 4;
// this is the line of sight
forecast = 50;
// step, in radians, the runner will turn if it finds an obstacle
turning_step = 0.5;
// this is the acceleration/deceleration rate
speed_step = 1;
runner.onEnterFrame = function() {
	// finding the end point of the line of sight
	forecast_x = this._x+forecast*Math.cos(angle);
	forecast_y = this._y+forecast*Math.sin(angle);
	// drawing the line of sight
	collisions.clear();
	collisions.lineStyle(1, 0x00ff00);
	collisions.moveTo(this._x, this._y);
	collisions.lineTo(forecast_x, forecast_y);
	// if an obstacle is in the line of sight
	if (obstacles.hitTest(forecast_x, forecast_y, true)) {
		// if the runner still has not turned
		if (turn == 0) {
			// decide where to turn
			turn = Math.floor(Math.random()*2)+1;
			switch (turn) {
			case 1 :
				angle -= turning_step;
				break;
			case 2 :
				angle += turning_step;
				break;
			}
		}
		// decelerate
		speed -= speed_step;
		if (speed<min_speed) {
			speed = min_speed;
		}
	} else {
		// accelerate
		speed += speed_step;
		if (speed>max_speed) {
			speed = max_speed;
		}
		// turn = 0 means "next time I will find an obstacle I will have to decide where to go"
		turn = 0;
	}
	// updating speed
	x_speed = speed*Math.cos(angle);
	y_speed = speed*Math.sin(angle);
	//updating position
	this._x += x_speed;
	this._y += y_speed;
	if (this._x>500) {
		this._x -= 500;
	}
	if (this._y>500) {
		this._y -= 500;
	}
	if (this._x<0) {
		this._x += 500;
	}
	if (this._y<0) {
		this._y += 500;
	}
};