// mouse cursor replacement
Mouse.hide();
_root.attachMovie("pointer","pointer",_root.getNextHighestDepth());
// max stars on stage
max_stars = 20;
// current stars on stage
stars_on_stage = 0;
// gravity
gravity = 0.1;
// this is the influence distance
// using influence and real_influence I perform the square root only once
// when the distance from the mouse and the star is less than real_influence
// then the star is affected by the mouse
influence = 625;
real_influence = Math.sqrt(influence);
// friction
friction = 0.9;
// divider, to make stars move slowly
divider = 50;
// main function
_root.onEnterFrame = function() {
	// should I add a star?
	if (stars_on_stage<max_stars) {
		//adding a star
		stars_on_stage++;
		starobj = _root.attachMovie("star", "star_"+x, _root.getNextHighestDepth(), {_x:Math.random()*450+25, _y:Math.random()*50-100});
		// star initial speed
		starobj.xspeed = 0;
		starobj.yspeed = 0;
		// function the star will execute at every frame
		starobj.onEnterFrame = function() {
			// gravity
			this.yspeed += gravity;
			// calculating the distance from the star and the mouse
			// without square roots
			dist_x = this._x-_root._xmouse;
			dist_y = this._y-_root._ymouse;
			distance = dist_x*dist_x+dist_y*dist_y;
			// if we are in the radius of influence...
			if (distance<influence) {
				// ...apply a force to the star
				// force is determined by mouse distance and speed
				xforce = mouse_speed*dist_x/divider;
				yforce = mouse_speed*dist_y/divider;
				this.xspeed += xforce;
				this.yspeed += yforce;
			}
			// adding friction 
			this.xspeed *= friction;
			this.yspeed *= friction;
			// updating position
			this._y += this.yspeed;
			this._x += this.xspeed;
			// make the star rotate
			this._rotation += (this.xspeed+this.yspeed);
			// if the star reaches the bottom of the stage, remove it
			if (this._y>300) {
				stars_on_stage--;
				this.removeMovieClip();
			}
		};
	}
};
// function to be executed by the mouse pointer
pointer.onEnterFrame = function() {
	// calculating the distance from the last point the mouse was spotted
	// and the current mouse position
	dist_x = this._x-_root._xmouse;
	dist_y = this._y-_root._ymouse;
	mouse_speed = Math.sqrt(dist_x*dist_x+dist_y*dist_y);
	// minimum speed = minimum force applied
	if (mouse_speed<0.2) {
		mouse_speed = 0.2;
	}
	// updating pointer position
	this._x = _root._xmouse;
	this._y = _root._ymouse;
 
};