Be my fan on FacebookCreate a Flash game like Gold Miner
- October 4, 2008 by Emanuele Feronato
- Filed under Actionscript 2, Flash, Game design | 22 Comments
Today I received an email from a reader asking me to make a tutorial of a game like Gold Miner.
It’s a Flash demo of a downloadable game, and I think its gameplay is interesting enough to deserve a tutorial.
The main actor in this game is the hook (in the original game, a claw).
The hook can have three states, that I defined this way:
rotate: that’s when the hook is rotating from left to right at the top of the screen. If the player presses the mouse the state turns to…
shoot: the hook moves in a fixed direction (the one it had when the player pressed the mouse) until it hits a gem or flies off the screen. Then the state turns again to…
rewind: the hook returns, in a straight path, to its initial position and changes the state to rotate, allowing the player to shoot again.
Rewind speed is the same as shoot speed if the hook did not take any boulder, while if the hook has a boulder attached, there will be a slowdown according to boulder size
Let’s see the commented code… remember that the hook is linked as pod while the gem as boulder
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 | // number of boulders in the game
boulders = 20;
for (x=1; x<=boulders; x++) {
// creating the boulders
bould = _root.attachMovie("boulder", "boulder_"+_root.getNextHighestDepth(), _root.getNextHighestDepth());
// placing them in random positions and with random dimensions
bould._x = Math.floor(Math.random()*400)+50;
bould._y = Math.floor(Math.random()*200)+150;
bould._width = Math.floor(Math.random()*30)+20;
bould._height = bould._width;
// setting picked attribute as false
// picked = false => the boulder has not been picked by the hook
// picked = true => the boulder has been picked
bould.picked = false;
// function to be executed at every frame for the boulder
bould.onEnterFrame = function() {
// if it's not been picked...
if (!this.picked) {
// check if the hook is in shoot mode and touched the boulder
// you'll see later what do hot_spot_x and hot_spot_y mean
if (pod_status == "shoot" and this.hitTest(hot_spot_x, hot_spot_y, true)) {
// set the hook on rewind mode
pod_status = "rewind";
// mark this boulder as picked
this.picked = true;
// determining the slowdown according to boulder size
slowdown = Math.floor(this._width/5);
}
}
else {
// the boulder has been picked, so move it as the hook moves
this._x = hot_spot_x;
this._y = hot_spot_y;
// if the hook status changed to rotate
// (this means: if the hook took a boulder and pulled it out to surface...
if (pod_status == "rotate") {
// remove the boulder
this.removeMovieClip();
}
}
};
}
// placing the hook on stage
_root.attachMovie("pod","pod",_root.getNextHighestDepth(),{_x:250});
// creating an empty movie clip to draw the rope
_root.createEmptyMovieClip("rod",_root.getNextHighestDepth());
// this is the rotation direction and speed
rotation_dir = 2;
// hook initial status
pod_status = "rotate";
// slowdown malus
slowdown = 0;
// function the hook will execute at every frame
pod.onEnterFrame = function() {
// getting pod status
switch (pod_status) {
case "rotate" :
// if the status is rotate, just rotate the hook according to rotation_dir
this._rotation += rotation_dir;
if (this._rotation == 80 or this._rotation == -80) {
// invert rotation_dir if the hook reaches its minimum (or maximum) rotation allowed
rotation_dir *= -1;
}
break;
case "shoot" :
// the hook has ben shoot
// (re)set slowdown malus to zero
slowdown = 0;
// moving the hook using trigonometry
this._x += 10*Math.cos(dir);
this._y += 10*Math.sin(dir);
// determining the hot spot of the hook
// the hot spot is the lowest corner of the hook (that acts like an harpoon in this case)
hot_spot_x = this._x+40*Math.cos(dir);
hot_spot_y = this._y+40*Math.sin(dir);
// if the hot spot goes off the stage
if (hot_spot_y>400 or hot_spot_x<0 or hot_spot_x>500) {
// then rewind the hook
pod_status = "rewind";
}
// draw a line from the hook starting position to its actual position
// this will simulate the rope
rod.clear();
rod.lineStyle(1,0x000000);
rod.moveTo(250,0);
rod.lineTo(this._x,this._y);
break;
case "rewind" :
// rewinding the hook...
// it may seem a nonsense determining the hot spot now, but I need id
// to move the boulder (if I have any boulder attached to the hook)
hot_spot_x = this._x+40*Math.cos(dir);
hot_spot_y = this._y+40*Math.sin(dir);
// moving the hook with slowdown malus (if any)
this._x -= (10-slowdown)*Math.cos(dir);
this._y -= (10-slowdown)*Math.sin(dir);
// if the hook returns in its initial position...
if (this._y<0) {
// then reset its position and set its status to rotate
this._y = 0;
this._x = 250;
pod_status = "rotate";
}
// drawing a line as seen in shoot status
rod.clear();
rod.lineStyle(1,0x000000);
rod.moveTo(250,0);
rod.lineTo(this._x,this._y);
break;
}
};
// when the mouse is clicked...
_root.onMouseDown = function() {
// if the status is rotate...
if (pod_status == "rotate") {
// save hook heading and convert it to radians
dir = (pod._rotation+90)*0.0174532925;
// set pod status to shoot
pod_status = "shoot";
}
}; |
And this is the result
As you can see, the basics have been reproduced.
Rate this post: 
(31 votes, average: 4.61 out of 5)
(31 votes, average: 4.61 out of 5)
Loading ...» Flash Templates provided by Template Monster are pre-made web design products developed using Flash technology.
They can be easily customized to meet the unique requirements of your project.
They can be easily customized to meet the unique requirements of your project.
22 Responses
Leave a Reply
TUTORIAL SERIES:
- Una guida completa al gioco del poker online e una selezione dei migliori casino online.
- casino online
- migliori casino online
- BlackJack online
- casinò online
Cool! I loved this game when I first played it :D
Very cool game idea!
hey really cool game…played it for 30mins+ and this is rare for me ;)
A million thanks Emanuele!
I’ll show you once I finish the game now.
Erv
Altho I was wondering how is it possible to add the Boulders manually and being able to move the base of the rope left n right.
this is awesome!!
This reminds me of Double Wire without the swinging. (DW)was AWESOME! but this is cool too.
This is great!
could you show how to also make lead boulders, like there are in the game?
I keep trying but it stuffs up.
thanks
I made a game based on this, but i have a problem… the boulders aren’t removed on the next frame (they tay tehre?!?!?) how to remove them?
[...] received a lot of emails asking me to add left-right movement to my Gold Miner clone and requiring more information about manually placing the [...]
@lolek,if you doing with frames you probably use bould_n.removeMovieClip();
Create some loop like
for (x=1; x<=boulders; x++)
{
[“bould_”+x}.removeMovieClip();
}
to clear stage or something…
or boulders may be in own “layer” then will be
boulders_ly.removeMovieClip()….
so many ways to do it, read help and this blog:)
Again, thanks for this great tutorial. I’m a newbie, so don’t consider this as criticising, I am merely trying to understand the code:
Wouldn’t it be better to determine the hotspot somewhere outside the switch, so it doesn’t have to be determined over and over?
hello.
can you send c# source code of this game to me?
fine thanks.
hello.
can you send c# code for this game to me?
fine thanks.
[...] difficulty: see something similar here. [...]
[...] To change the game a bit, in this version you can move the “mushroom” along the x axis with the mouse, and the launchable ball will move from left to right just like in Create a Flash game like Gold Miner. [...]
gr8 indeed……….
I wanted to ask what I needed to get and where I could get it in order to make games like these. Should I know about any specific programming languages in order to do this? Thanks for the help.
what about the stones? how you define them and make the hook go slower?
This is the actionscript 3 code of goldminer. Did this on my own as a mini project in my sem(at present).im a newbie to Flash.Here i get an error saying::
ArgumentError: Error #1063: Argument count mismatch on gold_edit_fla::MainTimeline/func3(). Expected 0, got 1.
can any1 fix this error…i have to submit this by 2moro morning….plz….
code is this:
var boulders:Number = 20, a:Number=1;
var pod_status:String = “rotate”;
var hot_spot_x:Number,hot_spot_y:Number;
var dir:Number;
var slowdown:Number=0,rotation_dir:Number = 2;;
for (a=1; a400 || hot_spot_x500)
{
pod_status = “rewind”;
}
rod.graphics.clear();
rod.graphics.lineStyle(1,0×000000);
rod.graphics.moveTo(250,0);
rod.graphics.lineTo(this.x,this.y);
break;
case “rewind” :
hot_spot_x = pod1.x+40*Math.cos(dir);
hot_spot_y = pod1.y+40*Math.sin(dir);
pod1.x -= (10-slowdown)*Math.cos(dir);
pod1.y -= (10-slowdown)*Math.sin(dir);
if (pod1.y<0) {
pod1.y = 0;
pod1.x = 250;
pod_status = "rotate";
}
rod.graphics.clear();
rod.graphics.lineStyle(1,0×000000);
rod.graphics.moveTo(250,0);
rod.graphics.lineTo(this.x,this.y);
break;
}
}
stage.addEventListener(MouseEvent.CLICK,func3);
function func3()
{
if (pod_status == "rotate")
{
//var z=pod1.rotation+90;
//dir = z*0.0174532925;
//dir = (pod1.rotation+90)*0.0174532925;
pod_status = "shoot";
}
}
in func3() i commented dir=(pod1.rotation+90)*0.0174532925;
it is also present…check the code using it…
Edited the above code a lot…n now im getin d goldminer game…but im having nly dis error.
ArgumentError: Error #2025: The supplied DisplayObject must be a child of the caller. at flash.display::DisplayObjectContainer/removeChild()
at gold_edit_name_fla::MainTimeline/func1()
here pod instance name is pod1 n for boulder is bould.
var boulders:Number = 20, a:Number=1;
var pod_status:String = “rotate”;
var hot_spot_x:Number,hot_spot_y:Number;
var dir:Number;
var slowdown:Number=0,rotation_dir:Number = 2;;
for (a=1; a400 || hot_spot_x500)
{
pod_status = “rewind”;
}
rod.graphics.clear();
rod.graphics.lineStyle(1,0×000000);
rod.graphics.moveTo(250,0);
rod.graphics.lineTo(pod1.x,pod1.y);
break;
case “rewind” :
hot_spot_x = pod1.x+40*Math.cos(dir);
hot_spot_y = pod1.y+40*Math.sin(dir);
pod1.x -= (10-slowdown)*Math.cos(dir);
pod1.y -= (10-slowdown)*Math.sin(dir);
if (pod1.y<0) {
pod1.y = 0;
pod1.x = 250;
pod_status = "rotate";
}
rod.graphics.clear();
rod.graphics.lineStyle(1,0×000000);
rod.graphics.moveTo(250,0);
rod.graphics.lineTo(pod1.x,pod1.y);
break;
}
}
stage.addEventListener(MouseEvent.CLICK,func3);
function func3(evt:MouseEvent):void
{
if (pod_status == "rotate")
{
dir = (pod1.rotation+90)*0.0174532925;
pod_status = "shoot";
}
}