package {
	import flash.display.Sprite;
	import flash.events.Event;
	public class bar extends Sprite {
		// variables used in this class
		private var point_x:int;
		private var point_y:int;
		// precision is the number of points I am going to calculate
		// on hero's circumference
		private var precision:int = 36;
		// calculating once for all 2*PI
		private var twopi: Number = Math.PI*2;
		// bar rotation speed
		public var rotspeed = 0.2;
		// main function
		public function bar() {
			// checking for collisions at every frame
			this.x = 250;
			this.y = 250;
			addEventListener(Event.ENTER_FRAME, check_collisions);
		}
		private function check_collisions(e:Event) {
			rotation += rotspeed;
			for (var i=0; i<precision; i++) {
				// checking for collisions between the hero and the bar
				point_x = as3circle(root).circle_hero.x + 25 * Math.cos(twopi*i/precision);
				point_y = as3circle(root).circle_hero.y - 25 * Math.sin(twopi*i/precision);
				if (this.hitTestPoint(point_x, point_y, true)) {
					// in case of collision, reset the hero, subtract 2 points to the score and slow down the bar
					as3circle(root).circle_hero.init();
					as3circle(root).add_score(-2);
					adjust_speed(-0.1);
				}
			}
		}
		public function adjust_speed(val) {
			rotspeed+=val;
			if (rotspeed<0.2) {
				rotspeed = 0.2;
			}
		}
	}
}

package {
	import flash.display.Sprite;
	import flash.events.Event;
	public class coin extends Sprite {
		// variables used in this class
		private var dist_x:int;
		private var dist_y:int;
		private var distance:int;
		// main function
		public function coin() {
			// calling place_coin function.
			// this function randomly places the coin in the field
			place_coin();
			// checking for collisions at every frame
			addEventListener(Event.ENTER_FRAME, check_collisions);
		}
		private function check_collisions(e:Event) {
			// determining the distance between the hero and the coin
			// notice how do I refer the hero
			dist_x = x - as3circle(root).circle_hero.x;
			dist_y = y - as3circle(root).circle_hero.y;
			distance = dist_x*dist_x+dist_y*dist_y;
			// 1809 = (hero radius + coin radius)^2
			// this way I don't have to perform a square root to distance
			if (distance < 1089) {
				// if the hero picks up a coin, then move it elsewhere, add one point to the score and speed up the bar
				as3circle(root).add_score(1);
				as3circle(root).rotating_bar.adjust_speed(0.2);
				place_coin();
			}
		}
		private function place_coin() {
			x = Math.floor(Math.random()*400)+50;
			y = Math.floor(Math.random()*400)+50;
		}
	}
}

package {
	import flash.display.Sprite;
	import flash.events.Event;
	public class as3circle extends Sprite {
		public var keyboard_input:keys;
		public var circle_hero = new circle;
		public var your_score = new score;
		public var level_wall = new wall;
		public var rotating_bar = new bar;
		public var my_score = 0;
		public var number_of_coins = 4;
		public function as3circle() {
			for (var i=1; i<=number_of_coins; i++) {
				var ingame_coin = new coin;
				addChild(ingame_coin);
			}
			addChild(your_score);
			addChild(circle_hero);
			addChild(rotating_bar);
			keyboard_input = new keys(this);
			addChild(level_wall);
			stage.addEventListener(Event.ENTER_FRAME,on_enter_frame);
		}
		public function on_enter_frame(event:Event) {
			if (keyboard_input.is_left()) {
				circle_hero.apply_force(-1,0);
			}
			if (keyboard_input.is_right()) {
				circle_hero.apply_force(1,0);
			}
			if (keyboard_input.is_up()) {
				circle_hero.apply_force(0,-1);
			}
			if (keyboard_input.is_down()) {
				circle_hero.apply_force(0,1);
			}
		}
		public function add_score(points) {
			my_score += points;
			if (my_score<0) {
				my_score = 0;
			}
			your_score.updatescore(my_score);
		}
	}
}