Creating a Flash Facebook application with the Facebook Actionscript API – part 2

package {
	import flash.display.Sprite;
	import fl.controls.Button;
	import flash.events.MouseEvent;
	import flash.text.TextField;
	// facebook libraries
	import com.facebook.Facebook;
	import com.facebook.utils.FacebookSessionUtil;
	import com.facebook.commands.notifications.*;
	import com.facebook.commands.friends.*;
	import com.facebook.commands.stream.*;
	import com.facebook.commands.users.*;
	import com.facebook.events.*;
	import com.facebook.data.users.*;
	import com.facebook.data.friends.*;
	import com.facebook.net.FacebookCall;
 
	public class facebook_demo extends Sprite {
		var vars_field:TextField=new TextField  ;
		var friends_field:TextField=new TextField  ;
		var my_button:Button;
		var fbook:Facebook;
		// these are the api and secret keys you should be used to
		var api_key:String="xxxxxxxxxxxxxxxxxxxxxxx";
		var secret_key:String="yyyyyyyyyyyyyyyyyyyyyyy";
		// starting a new facebook session
		var fb_session:FacebookSessionUtil=new FacebookSessionUtil(api_key,secret_key,loaderInfo);
		// in this object I will store all variables Facebook will pass to the movie
		var passed_vars:Object;
		// this variable will hold all facebook API calls
		var fbcall:FacebookCall;
		public function facebook_demo() {
			// just placing some buttons...
			place_buttons();
			// just creating a text field...
			create_vars_field();
			// initializing the session
			fbook=fb_session.facebook;
			// this function will just print out all variables Facebook is passing to the movie
			get_vars();
			// getting friends uids (unique ids)
			fbcall = new GetFriends();
			fbook.post(fbcall);
			// function on_get_friends will be called once the post is completed
			fbcall.addEventListener(FacebookEvent.COMPLETE, on_get_friends);
		}
		// function to be called after GetFriends has finished
		function on_get_friends(e:FacebookEvent):void {
			var friends = (e.data as GetFriendsData).friends;
			var friends_num:int=friends.length;
			var uids:Array = new Array();
			// loading all friends uids into an array
			for (var i:int=0; i<friends_num; i++) {
				var user=friends.getItemAt(i) as FacebookUser;
				uids.push(user.uid);
			}
			// retrieving informations for all uids contained in the uids array
			fbcall=new GetInfo(uids,[GetInfoFieldValues.ALL_VALUES]);
			fbook.post(fbcall);
			// the function on_friend_list_loaded will be called once the post is completed
			fbcall.addEventListener(FacebookEvent.COMPLETE, on_friend_list_loaded);
		}
		// function to be called after GetInfo has finished
		function on_friend_list_loaded(e:FacebookEvent) {
			var friends_data = ((e.data as GetInfoData).userCollection);
			var friends_num=friends_data.length;
			// scanning all friends array and printing name and last name of each one
			for (var i:int=0; i<friends_num; i++) {
				var user=friends_data.getItemAt(i);
				friends_field.appendText(user.first_name+" "+user.last_name+"\n");
			}
		}
		// this is the core function, the one that will handle clicks on buttons and publising notes or stories according
		// to the button I am pressing
		function onclick(event:MouseEvent):void {
			// retrieving the user id (it's one of the variables passed by Facebook)
			var uid:Number=Number(passed_vars["fb_sig_user"]);
			switch (event.currentTarget.label) {
				case "Publish a note" :
					// publishing a note
					fbcall=new SendNotification([uid],"just sent a self-notification using <a href = \"http://apps.facebook.com/flash_demo/\">Facebook Flash Demo</a>","user_to_user");
					fbook.post(fbcall);
					break;
				case "Publish a story" :
					// publishing a story
					fbcall=new PublishPost("is using Facebook Flash Demo",{'href':'http://apps.facebook.com/flash_demo/','name':'Facebook Flash Demo','description':'that\'s it','caption':'this image was published by a Flash Movie','media':[{'type': 'image','src':  'http://www.gamemummy.com/facebook/flash_demo/api.jpg', 'href': 'http://apps.facebook.com/flash_demo/'}]},[{'href':'http://apps.facebook.com/flash_demo/','text':'Visit Facebook Flash Demo'}],uid.toString());
					fbook.post(fbcall);
					break;
			}
		}
		function create_vars_field():void {
			addChild(vars_field);
			vars_field.width=340;
			vars_field.height=320;
			vars_field.x=0;
			vars_field.y=10;
			vars_field.text="DEFAULT VARS PASSED BY FACEBOOK:\n\n";
			addChild(friends_field);
			friends_field.width=340;
			friends_field.height=320;
			friends_field.x=350;
			friends_field.y=10;
			friends_field.text="YOUR FACEBOOK FRIENDS (scroll with mousewheel):\n\n";
		}
		function get_vars():void {
			var varname:String;
			var varvalue:String;
			passed_vars=root.loaderInfo.parameters;
			for (varname in passed_vars) {
				varvalue=String(passed_vars[varname]);
				vars_field.appendText(varname+":\t"+varvalue+"\n");
			}
		}
		function place_buttons():void {
			var bnames:Array=new Array("Publish a note","Publish a story");
			for (var i:int=0; i<2; i++) {
				my_button=new Button  ;
				addChild(my_button);
				my_button.label=bnames[i];
				my_button.move(225+150*i,350);
				my_button.addEventListener(MouseEvent.CLICK,onclick);
			}
		}
	}
}