Scaling objects with Box2D

I would like to start talking about a Shrink it prototype but I noticed it’s most based upon objects resizing.

So before trying to replicate the game, let’s start with some info about object scaling in Box2D

The first interesting thing about Box2D scaling is you can’t scale a Box2D body.

And the tutorial is over :)

Now, what about deleting an existing object and replacing it with a smaller/bigger one?

That’s the right way you can do it.

In this example, I am going to resize the simplest object ever… a circle. You know to scale a circle you simply have to change its radius.

So the trick is delete the previous circle, and create a new one.

But it’s not that easy.

In Box2D, there are bodies and shapes. A body is a collection of shapes. A circle, in this specific case, is a body with one circle shape. So to scale the circle, we must remove the initial circle shape from the body, and add a new one. We don’t have to touch the body, only the shape.

Then, since different circles have different masses, we must assign a new mass to the body.

In this script I assume you know how to select a Box2D object with the mouse. If you aren’t familiar with it, read Understanding pixels and meters with Box2D and how to select an object with mouse – part 1 and part 2.

Once you know how to select an object, it’s all a matter of geometry: to scale a circle you just have to change its radius, and every regular polygon has its formula. To tell the truth, I should improve my geometry skills so if you have the formula to resize hexagons or similar shapes, you’re welcome!

So this code has nothing new except lines 87-106 that are fully commented:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113

package {
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import Box2D.Dynamics.*;
	import Box2D.Collision.*;
	import Box2D.Collision.Shapes.*;
	import Box2D.Common.Math.*;
	public class shrink extends Sprite {
		var body:b2Body;
		public var m_world:b2World;
		public var m_iterations:int=10;
		public var m_timeStep:Number=1.0/30.0;
		private var mousePVec:b2Vec2 = new b2Vec2();
		public function shrink() {
			var worldAABB:b2AABB = new b2AABB();
			var bodyDef:b2BodyDef;
			var boxDef:b2PolygonDef;
			var circleDef:b2CircleDef;
			worldAABB.lowerBound.Set(-100.0, -100.0);
			worldAABB.upperBound.Set(100.0, 100.0);
			m_world=new b2World(worldAABB,new b2Vec2(0,10),true);
			// debug draw start
			var m_sprite:Sprite;
			m_sprite = new Sprite();
			addChild(m_sprite);
			var dbgDraw:b2DebugDraw = new b2DebugDraw();
			var dbgSprite:Sprite = new Sprite();
			m_sprite.addChild(dbgSprite);
			dbgDraw.m_sprite=m_sprite;
			dbgDraw.m_drawScale=30;
			dbgDraw.m_alpha=1;
			dbgDraw.m_fillAlpha=0.5;
			dbgDraw.m_lineThickness=1;
			dbgDraw.m_drawFlags=b2DebugDraw.e_shapeBit;
			m_world.SetDebugDraw(dbgDraw);
			// debug draw end
			bodyDef = new b2BodyDef();
			bodyDef.position.Set(10, 12);
			boxDef = new b2PolygonDef();
			boxDef.SetAsBox(30, 3);
			boxDef.friction=0.3;
			boxDef.density=0;
			body=m_world.CreateBody(bodyDef);
			body.CreateShape(boxDef);
			body.SetMassFromShapes();
			//
			bodyDef = new b2BodyDef();
			bodyDef.position.x=5;
			bodyDef.position.y=5;
			circleDef = new b2CircleDef();
			circleDef.radius=3;
			circleDef.density=1.0;
			circleDef.friction=0.5;
			circleDef.restitution=0.2;
			body=m_world.CreateBody(bodyDef);
			body.CreateShape(circleDef);
			body.SetMassFromShapes();
			//
			addEventListener(Event.ENTER_FRAME, Update, false, 0, true);
			stage.addEventListener(MouseEvent.MOUSE_DOWN, GetBodyAtMouse);
		}
		public function GetBodyAtMouse(includeStatic:Boolean=false):b2Body {
			var mouseXWorldPhys = (mouseX)/30;
			var mouseYWorldPhys = (mouseY)/30;
			mousePVec.Set(mouseXWorldPhys, mouseYWorldPhys);
			var aabb:b2AABB = new b2AABB();
			aabb.lowerBound.Set(mouseXWorldPhys - 0.001, mouseYWorldPhys 
			- 0.001);
			aabb.upperBound.Set(mouseXWorldPhys + 0.001, mouseYWorldPhys 
			+ 0.001);
			var k_maxCount:int=10;
			var shapes:Array = new Array();
			var count:int=m_world.Query(aabb,shapes,k_maxCount);
			var body:b2Body=null;
			for (var i:int = 0; i < count; ++i) {
				if (shapes[i].GetBody().IsStatic()==false||includeStatic) {
					var tShape:b2Shape=shapes[i] as b2Shape;
					var inside:Boolean=tShape.TestPoint(tShape.GetBody().GetXForm(),mousePVec);
					if (inside) {
						body=tShape.GetBody();
						break;
					}
				}
			}
			// if I selected a body...
			if (body) {
				// I know it's a circle, so I am creating a b2CircleShape variable
				var circle:b2CircleShape=body.GetShapeList() as b2CircleShape;
				// getting the radius..
				var r=circle.GetRadius();
				// removing the circle shape from the body
				body.DestroyShape(circle);
				// creating a new circle shape
				var circleDef:b2CircleDef;
				circleDef = new b2CircleDef();
				// calculating new radius
				circleDef.radius=r*0.9;
				circleDef.density=1.0;
				circleDef.friction=0.5;
				circleDef.restitution=0.2;
				// attach the shape to the body
				body.CreateShape(circleDef);
				// determine new body mass
				body.SetMassFromShapes();
			}
			return body;
		}
		public function Update(e:Event):void {
			m_world.Step(m_timeStep, m_iterations);
		}
	}
}

And this is the result:

Click on the circle to scale it down by 10%

Download the source code.

Next time, I’ll show you how to scale squares and triangles.

Rate this post: 1 Star2 Stars3 Stars4 Stars5 Stars (4 votes, average: 2.75 out of 5)
Loading ... Loading ...
If you found this post useful, please consider a small donation.
» Flash Templates provided by Template Monster are pre-made web design products developed using Flash technology.
They can be easily customized to meet the unique requirements of your project.

8 Responses

  1. Cataclysm Studios says:
    December 12, 2009 at 7:56 pm

    How about making it smoothly scale? I think that’d be a pretty cool effect.

    Reply
  2. Yarden Refaeli says:
    December 12, 2009 at 8:44 pm

    Nice post.
    @Cataclysm: you can use TweenLite/Max and animate the sprite/movieclip each click, and then every time you “resize” a Box2D item, the sprite will smoothly scale to the new object’s dimmensions.

    Emanuele, feel free to suggest another creative solution ;)

    Reply
  3. Andy says:
    December 14, 2009 at 7:49 pm

    The exact thing I was trying to work out last week! Have now binned that part of project and am doing my scaling with tweens… ah well. Cheers anyway! ;)

    Reply
  4. Kala says:
    December 14, 2009 at 9:10 pm

    Hello,

    it is possible create conveyor?
    I want to make simple simulation and I generate randomly some object that fall down on one side and then I want to move it automatically by conveyor.

    Thank you. Kala

    Reply
  5. seren says:
    December 15, 2009 at 4:48 pm

    Is there a way to do this with custom shapes without * the coords by a scale each time you recreate the shape?

    Reply
  6. Scaling objects with Box2D – part 2 : Emanuele Feronato - italian geek and PROgrammer says:
    December 16, 2009 at 12:47 am

    [...] the first part I showed you how to scale a [...]

    Reply
  7. Interview with Nick Pearce, the guy behind Shrink it : Emanuele Feronato - italian geek and PROgrammer says:
    December 16, 2009 at 11:01 pm

    [...] Shrink it? You should, because it’s a very popular game and because it inspired me to write Scaling objects with Box2D – part 1 and [...]

    Reply
  8. Shrink it Box2D prototype : Emanuele Feronato - italian geek and PROgrammer says:
    January 5, 2010 at 5:22 pm

    [...] post continues Scaling objects with Box2D and Scaling objects with Box2D – part 2, with these [...]

    Reply

Leave a Reply