Basic Filler engine with Box2D – part 3

Read all posts about "" game

Here we are with the 3rd part… this time we’ll manage collision detection.

I recommend to read step 1 and 2 before continuing.

You should how to manage collisions with Box2D, and if not go and read Understanding how Box2D manages collisions, but this time we won’t use the collision handler.

Since all collisions we have to manage are among circles, I’ll simply use the Pythagoras theorem.

The only thing that differs from the original concept is when you touch a ball or the boundaries, the ball you are drawing does not disappear but falls down. Just to make something different…

package {
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import Box2D.Dynamics.*;
	import Box2D.Collision.*;
	import Box2D.Collision.Shapes.*;
	import Box2D.Common.Math.*;
	public class colorballz extends Sprite {
		public var m_dbgSprite;
		public var m_world:b2World;
		public var m_phys_scale:Number=30;
		public var m_timestep:Number=1.0/30.0;
		public var m_iterations:Number=10.0;
		public var initX:Number=0.0;
		public var initY:Number=0.0;
		public var drawing:Boolean=false;
		public var b:b2Body;
		public var the_ball:ball;
		public var the_enemy:enemy;
		public function colorballz() {
			var gravity:b2Vec2=new b2Vec2(0,9.8);
			var worldAABB:b2AABB = new b2AABB();
			worldAABB.lowerBound.Set(-1000,-1000);
			worldAABB.upperBound.Set(1000,1000);
			m_world=new b2World(worldAABB,gravity,true);
			//Add Our Ground
			AddStaticBox(250/m_phys_scale,510/m_phys_scale,250/m_phys_scale,10/m_phys_scale);
			AddStaticBox(250/m_phys_scale,-10/m_phys_scale,250/m_phys_scale,10/m_phys_scale);
			AddStaticBox(-10/m_phys_scale,250/m_phys_scale,10/m_phys_scale,250/m_phys_scale);
			AddStaticBox(510/m_phys_scale,250/m_phys_scale,10/m_phys_scale,250/m_phys_scale);
			//Add enemies
			for (var x:int=1; x<=3; x++) {
				// the first parameter is enemy's radius
				addEnemy(10);
			}
			addEventListener(Event.ENTER_FRAME,Update);
			stage.addEventListener(MouseEvent.MOUSE_DOWN,mousePressed);
			stage.addEventListener(MouseEvent.MOUSE_MOVE,mouseMoved);
			stage.addEventListener(MouseEvent.MOUSE_UP,mouseReleased);
		}
		public function mousePressed(e:MouseEvent) {
			initX=e.localX;
			initY=e.localY;
			the_ball = new ball();
			the_ball.x=mouseX;
			the_ball.y=mouseY;
			the_ball.width=1;
			the_ball.height=1;
			addChild(the_ball);
			drawing=true;
		}
		public function mouseMoved(e:MouseEvent) {
			if (drawing) {
				the_ball.x=mouseX;
				the_ball.y=mouseY;
			}
		}
		public function mouseReleased(e:MouseEvent) {
			if (drawing) {
				drawing=false;
				addCircle(mouseX,mouseY,the_ball.width/2,the_ball);
			}
		}
		public function addCircle(_x:Number, _y:Number, _radius:Number,ballclip:ball) {
			var bd:b2BodyDef = new b2BodyDef();
			var cd:b2CircleDef = new b2CircleDef();
			var area:Number=Math.floor(_radius*_radius*Math.PI/25)/100;
			cd.radius=Math.abs(_radius)/m_phys_scale;
			cd.density=2;
			cd.restitution=0.7;
			cd.friction=2;
			bd.position.Set(_x/m_phys_scale, _y/ m_phys_scale);
			bd.userData=ballclip;
			b=m_world.CreateBody(bd);
			b.CreateShape(cd);
			b.SetMassFromShapes();
		}
		public function addEnemy(_radius:Number) {
			var x_speed:Number=Math.random()*10;
			var bd:b2BodyDef = new b2BodyDef();
			var cd:b2CircleDef = new b2CircleDef();
			the_enemy = new(enemy);
			cd.radius=Math.abs(_radius)/m_phys_scale;
			cd.density=20;
			// setting restitution to 1 should grant the enemy won't lose speed when bouncing
			// on STATIC objects
			cd.restitution=1;
			cd.friction=2;
			// randomly placing the enemy
			bd.position.Set((Math.random()*300+50)/m_phys_scale, (Math.random()*300+50)/ m_phys_scale);
			bd.userData=the_enemy;
			bd.userData.name="enemy";
			bd.userData.width=_radius*2;
			bd.userData.height=_radius*2;
			addChild(the_enemy);
			b=m_world.CreateBody(bd);
			b.CreateShape(cd);
			b.SetMassFromShapes();
			// assigning random speed to enemy
			b.m_linearVelocity.x=x_speed;
			b.m_linearVelocity.y=10-x_speed;
		}
		public function AddStaticBox(_x:Number,_y:Number,_halfwidth:Number,_halfheight:Number) {
			var bodyDef:b2BodyDef = new b2BodyDef();
			bodyDef.position.Set(_x,_y);
			var boxDef:b2PolygonDef = new b2PolygonDef();
			boxDef.SetAsBox(_halfwidth,_halfheight);
			boxDef.density=0.0;
			var body:b2Body=m_world.CreateBody(bodyDef);
			body.CreateShape(boxDef);
			body.SetMassFromShapes();
		}
		public function Update(e:Event) {
			var dist_x:Number;
			var dist_y:Number;
			var distance:Number;
			// variable to handle enemy speed
			var enemy_speed:Number;
			// variable to handle the speed offset:it's the ratio between
			// the real enemy speed and the minimum allowed speed
			var speed_offset:Number;
			if (drawing) {
				the_ball.width+=2;
				the_ball.height+=2;
				// checking if the ball is touching boundaries
				if (the_ball.x-the_ball.width/2<0||the_ball.x+the_ball.width/2>500||the_ball.y-the_ball.width/2<0||the_ball.y+the_ball.width/2>500) {
					drawing=false;
					addCircle(mouseX,mouseY,the_ball.width/2,the_ball);
				}
			}
			m_world.Step(m_timestep,m_iterations);
			for (var bb:b2Body=m_world.m_bodyList; bb; bb=bb.m_next) {
				if (bb.m_userData is Sprite) {
					if (bb.m_userData.name=="enemy") {
						// determining enemy speed
						enemy_speed=Math.abs(bb.GetLinearVelocity().x)+Math.abs(bb.GetLinearVelocity().y);
						// if the speed is too slow... (lower than 10)
						if (enemy_speed<10) {
							// calculating the offset
							speed_offset=10/enemy_speed;
							// multiplying the horizontal and vertical components of the speed
							// by the offset
							bb.m_linearVelocity.x=bb.GetLinearVelocity().x*speed_offset;
							bb.m_linearVelocity.y=bb.GetLinearVelocity().y*speed_offset;
						}
					}
					bb.m_userData.x=bb.GetPosition().x*30;
					bb.m_userData.y=bb.GetPosition().y*30;
					// if I am drawing the ball...
					if (drawing) {
						// determining the distance between the current ball and the one I am drawing
						dist_x=the_ball.x-bb.m_userData.x;
						dist_y=the_ball.y-bb.m_userData.y;
						// notice I am not using any square root to make the script lighter
						distance=dist_x*dist_x+dist_y*dist_y;
						// if balls collide...
						if (distance<(the_ball.width/2+bb.m_userData.width/2)*(the_ball.width/2+bb.m_userData.width/2)) {
							// release the drawing ball and set drawing to false, as if I released the mouse
							// here you should lose a life...
							drawing=false;
							addCircle(mouseX,mouseY,the_ball.width/2,the_ball);
						}
					}
				}
			}
		}
	}
}

And this is the result:

You should already know ho to play...

Download the source code and make your own filler game

Get the most popular Phaser 3 book

Through 202 pages, 32 source code examples and an Android Studio project you will learn how to build cross platform HTML5 games and create a complete game along the way.

Get the book

214 GAME PROTOTYPES EXPLAINED WITH SOURCE CODE
// 1+2=3
// 100 rounds
// 10000000
// 2 Cars
// 2048
// A Blocky Christmas
// A Jumping Block
// A Life of Logic
// Angry Birds
// Angry Birds Space
// Artillery
// Astro-PANIC!
// Avoider
// Back to Square One
// Ball Game
// Ball vs Ball
// Ball: Revamped
// Balloon Invasion
// BallPusher
// Ballz
// Bar Balance
// Bejeweled
// Biggification
// Block it
// Blockage
// Bloons
// Boids
// Bombuzal
// Boom Dots
// Bouncing Ball
// Bouncing Ball 2
// Bouncy Light
// BoxHead
// Breakout
// Bricks
// Bubble Chaos
// Bubbles 2
// Card Game
// Castle Ramble
// Chronotron
// Circle Chain
// Circle Path
// Circle Race
// Circular endless runner
// Cirplosion
// CLOCKS - The Game
// Color Hit
// Color Jump
// ColorFill
// Columns
// Concentration
// Crossy Road
// Crush the Castle
// Cube Jump
// CubesOut
// Dash N Blast
// Dashy Panda
// Deflection
// Diamond Digger Saga
// Don't touch the spikes
// Dots
// Down The Mountain
// Drag and Match
// Draw Game
// Drop Wizard
// DROP'd
// Dudeski
// Dungeon Raid
// Educational Game
// Elasticity
// Endless Runner
// Erase Box
// Eskiv
// Farm Heroes Saga
// Filler
// Flappy Bird
// Fling
// Flipping Legend
// Floaty Light
// Fuse Ballz
// GearTaker
// Gem Sweeper
// Globe
// Goat Rider
// Gold Miner
// Grindstone
// GuessNext
// Helicopter
// Hero Emblems
// Hero Slide
// Hexagonal Tiles
// HookPod
// Hop Hop Hop Underwater
// Horizontal Endless Runner
// Hundreds
// Hungry Hero
// Hurry it's Christmas
// InkTd
// Iromeku
// Jet Set Willy
// Jigsaw Game
// Knife Hit
// Knightfall
// Legends of Runeterra
// Lep's World
// Line Rider
// Lumines
// Magick
// MagOrMin
// Mass Attack
// Math Game
// Maze
// Meeblings
// Memdot
// Metro Siberia Underground
// Mike Dangers
// Mikey Hooks
// Nano War
// Nodes
// o:anquan
// One Button Game
// One Tap RPG
// Ononmin
// Pacco
// Perfect Square!
// Perfectionism
// Phyballs
// Pixel Purge
// PixelField
// Planet Revenge
// Plants Vs Zombies
// Platform
// Platform game
// Plus+Plus
// Pocket Snap
// Poker
// Pool
// Pop the Lock
// Pop to Save
// Poux
// Pudi
// Pumpkin Story
// Puppet Bird
// Pyramids of Ra
// qomp
// Quick Switch
// Racing
// Radical
// Rebuild Chile
// Renju
// Rise Above
// Risky Road
// Roguelike
// Roly Poly
// Run Around
// Rush Hour
// SameGame
// SamePhysics
// Save the Totem
// Security
// Serious Scramblers
// Shrink it
// Sling
// Slingy
// Snowflakes
// Sokoban
// Space Checkers
// Space is Key
// Spellfall
// Spinny Gun
// Splitter
// Spring Ninja
// Sproing
// Stabilize!
// Stack
// Stick Hero
// String Avoider
// Stringy
// Sudoku
// Super Mario Bros
// Surfingers
// Survival Horror
// Talesworth Adventure
// Tetris
// The Impossible Line
// The Moops - Combos of Joy
// The Next Arrow
// Threes
// Tic Tac Toe
// Timberman
// Tiny Wings
// Tipsy Tower
// Toony
// Totem Destroyer
// Tower Defense
// Trick Shot
// Tunnelball
// Turn
// Turnellio
// TwinSpin
// vvvvvv
// Warp Shift
// Way of an Idea
// Whack a Creep
// Wheel of Fortune
// Where's my Water
// Wish Upon a Star
// Word Game
// Wordle
// Worms
// Yanga
// Yeah Bunny
// Zhed
// zNumbers